Android多渠道打包配置

// 读取 local.properties 配置信息
val localProperties = gradleLocalProperties(rootDir)

android {
    // ...
    // 签名配置
    signingConfigs {
        val release by creating {
            storeFile = rootProject.file(localProperties["storeFile"].toString())
            storePassword = localProperties["storePassword"].toString()
            keyAlias = localProperties["keyAlias"].toString()
            keyPassword = localProperties["keyPassword"].toString()
        }
    }

    // 构建类型配置
    buildTypes {
        val release by getting {
            isMinifyEnabled = true
            signingConfig = signingConfigs.getByName("release")
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
            android.applicationVariants.all { variant ->
                variant.outputs.all {
                    if (this is com.android.build.gradle.internal.api.ApkVariantOutputImpl) {
                        outputFileName = "渠道测试-${variant.versionName}-${variant.versionCode}-${variant.buildType.name}.apk"
                    }
                }
                true
            }
        }
        getByName("debug") {
            isMinifyEnabled = true
            signingConfig = signingConfigs.getByName("release")
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }
}

// ...
android {
    // ...
    buildTypes {
        val release by getting {
            // ...
            // 修改打包文件名配置
            android.applicationVariants.all { variant ->
                variant.outputs.all {
                    if (this is com.android.build.gradle.internal.api.ApkVariantOutputImpl) {
                        outputFileName = "渠道测试-${variant.flavorName}-${variant.versionName}-${variant.versionCode}-${variant.buildType.name}.apk"
                    }
                }
                true
            }
        }
        // ...
    }
    
    // 定义一个维度
    // 解决报错: All flavor must now belong to a named flavor dimension
    flavorDimensions += listOf("default")
    
    // 渠道配置
    productFlavors {
        create("product1") {
            dimension = "default"
        }
        create("product2") {
            dimension = "default"
        }
    }
}

// ...
android {
    // ...
    // 渠道配置
    productFlavors {
        create("product1") {
            dimension = "default"
            // 每个渠道可以指定不同的包名，版本信息等
            applicationId = "com.viifo.flavorsdemo.product1"
            versionCode = 1
            versionName = "1.0"
            
            // buildConfigField 会配置到 BuildConfig 文件中, 在代码中使用用于判断是什么渠道
            // 实际上配置了渠道 BuildConfig 已经存在渠道信息变量 FLAVOR, 这里的 PRODUCT_FLAVORS 只做演示
            buildConfigField("String", "PRODUCT_FLAVORS", "\"product1\"")
            // 修改 AndroidManifest.xml 里渠道变量， 在 AndroidManifest。xml 中使用 ${app_icon} 引用
            manifestPlaceholders += mapOf("app_icon" to "@mipmap/ic_launcher")
            // 动态添加 string.xml 字段
            // 必须要保证 string.xml 中没有该字段，否则会出现同名的字符串，引起冲突
            resValue("String", "app_name", "渠道测试1")
        }
        create("product2") {
            dimension = "default"
            // 每个渠道可以指定不同的包名，版本信息等
            applicationId = "com.viifo.flavorsdemo.product2"
            versionCode = 1
            versionName = "1.0"
            
            // buildConfigField 会配置到 BuildConfig 文件中, 在代码中使用用于判断是什么渠道
            // 实际上配置了渠道 BuildConfig 已经存在渠道信息变量 FLAVOR, 这里的 PRODUCT_FLAVORS 只做演示
            buildConfigField("String", "PRODUCT_FLAVORS", "\"product2\"")
            // 修改 AndroidManifest.xml 里渠道变量， 在 AndroidManifest。xml 中使用 ${app_icon} 引用
            manifestPlaceholders += mapOf("app_icon" to "@mipmap/ic_launcher")
            // 动态添加 string.xml 字段
            // 必须要保证 string.xml 中没有该字段，否则会出现同名的字符串，引起冲突
            resValue("String", "app_name", "渠道测试2")
        }
    }
}

// ...
android {
    // ...
    // 渠道配置
    productFlavors {
        create("product1") {
            dimension = "default"
            // 每个渠道可以指定不同的包名，版本信息等
            applicationId = "com.viifo.flavorsdemo.product1"
            versionCode = 1
            versionName = "1.0"
        }
        create("product2") {
            dimension = "default"
            // 每个渠道可以指定不同的包名，版本信息等
            applicationId = "com.viifo.flavorsdemo.product2"
            versionCode = 1
            versionName = "1.0"
        }
    }
    
    // 指定渠道资源目录
    sourceSets {
        // 默认使用资源( 配置夜间模式资源 res-night )
        getByName("main") {
            res.srcDirs("src/main/res", "src/main/res-night")
            assets.srcDirs("src/assets")
        }
        // 渠道资源配置
        getByName("product1") {
            res.srcDirs("src/main/res-prod")
            assets.srcDirs("src/assets-product1")
        }
        getByName("product2") {
            res.srcDirs("src/main/res-other")
            assets.srcDirs("src/assets-product2")
        }
    }
    
}

// ...
android {
    // ...
    // 定义纬度
    flavorDimensions += listOf("product", "style")
    // 渠道配置
    productFlavors {
       create("product1") {
           dimension = "default"
       }
       create("product2") {
            dimension = "default"
       }
       create("style1") {
            dimension = "style"
       }
       create("style2") {
            dimension = "style"
       }
    }
}